[WIP] Add isoneto trait and use in similar

[jishnub]

This implements the suggestion in #41946 (comment), which makes it possible for range wrappers to opt into the methods for OneTo axes. In particular, this targets similar, which means that any axis type that opts in to the OneTo-like behavior would avoid hitting methods from OffsetArrays. In particular, avoiding piracy has been a requested feature in OffsetArrays for a while (e.g. JuliaArrays/OffsetArrays.jl#306), and this allows individual types to circumvent the issue.

An example of usage:

struct MyOneTo{T<:Integer} <: Base.AbstractOneTo{T}
   r :: Base.OneTo{T}
end
MyOneTo(n::Integer) = MyOneTo(Base.OneTo(n))

Base.first(r::MyOneTo) = first(r.r)
Base.length(r::MyOneTo) = length(r.r)
Base.last(r::MyOneTo) = last(r.r)

struct OneToWrapper{T, R<:AbstractUnitRange{T}} <: AbstractUnitRange{T}
   r :: R
end
OneToWrapper(n::Integer) = OneToWrapper(MyOneTo(n))

Base.first(r::OneToWrapper) = first(r.r)
Base.length(r::OneToWrapper) = length(r.r)
Base.last(r::OneToWrapper) = last(r.r)
Base.step(r::OneToWrapper) = step(r.r)

With this, on master, we obtain

julia> similar(ones(4), MyOneTo(3))
3-element Vector{Float64}:
 6.6992345876623e-310
 6.6992298218695e-310
 0.0

julia> similar(ones(4), Int, OneToWrapper(3))
ERROR: MethodError: no method matching similar(::Vector{Float64}, ::Type{Int64}, ::Base.HasOneToAxes{false, Tuple{OneToWrapper{Int64, MyOneTo{Int64}}}})
The function `similar` exists, but no method is defined for this combination of argument types.

This is because similar considers a OneToWrapper to be an offset axis. In particular, with OffsetArrays loaded, we obtain

julia> similar(ones(4), Int, OneToWrapper(3))
3-element OffsetArray(::Vector{Int64}, 1:3) with eltype Int64 with indices 1:3:
               1
 127218676454144
 127218707731840

However, if we further define

Base.isoneto(::Type{OneToWrapper{T,R}}) where {T,R} = Base.isoneto(R)

we obtain

julia> similar(ones(4), Int, OneToWrapper(3))
3-element Vector{Int64}:
 135593745193136
 135593843627392
 135593743902368

Now this method is handled by Base, as the OneToWrapper behaves like a OneTo. This is now unaffected by OffsetArrays being loaded.

Closes #41946.